Name

settings()

Description

The settings() function is new with Processing 3.0. It's not needed in most sketches. It's only useful when it's absolutely necessary to define the parameters to size() with a variable. Alternately, the settings() function is necessary when using Processing code outside the Processing Development Environment (PDE). For example, when using the Eclipse code editor, it's necessary to use settings() to define the size() and smooth() values for a sketch..

The settings() method runs before the sketch has been set up, so other Processing functions cannot be used at that point. For instance, do not use loadImage() inside settings(). The settings() method runs "passively" to set a few variables, compared to the setup() command that call commands in the Processing API.

Examples

  • // Run code at full screen using the default renderer
    
    int x = 0;
    
    void settings() {
      fullScreen();
    }
    
    void setup() {
      background(0);
      noStroke();
      fill(102);
    }
    
    void draw() {
      rect(x, height*0.2, 1, height*0.6); 
      x = x + 2;
    }
    
  • // Run code at full screen using the P2D renderer
    // on screen 2 of a multiple monitor hardware setup
    
    int x = 0;
    
    void settings() {
      fullScreen(P2D, 2);
    }
    
    void setup() {
      background(0);
      noStroke();
      fill(102);
    }
    
    void draw() {
      rect(x, height*0.2, 1, height*0.6); 
      x = x + 2;
    }
    
  • // Run code at full screen using the P2D renderer
    // across all screens on a multiple monitor setup
    
    int x = 0;
    
    void settings() {
      fullScreen(P2D, SPAN);
    }
    
    void setup() {
      background(0);
      noStroke();
      fill(102);
    }
    
    void draw() {
      rect(x, height*0.2, 1, height*0.6); 
      x = x + 2;
    }
    
  • int w = 200;
    int h = 200;
    int x = 0;
    
    void settings() {
      size(w, h);
    }
    
    void setup() {
      background(0);
      noStroke();
      fill(102);
    }
    
    void draw() {
      rect(x, 10, 1, 180); 
      x = x + 2;
    }
    

Syntax

  • settings()

Return

  • void