Name

createImage()

Description

Creates a new PImage (the datatype for storing images). This provides a fresh buffer of pixels to play with. Set the size of the buffer with the width and height parameters. The format parameter defines how the pixels are stored. See the PImage reference for more information.

Be sure to include all three parameters, specifying only the width and height (but no format) will produce a strange error.

Advanced users please note that createImage() should be used instead of the syntax new PImage().

Examples

  • size(400,400);
    PImage img = createImage(264, 264, RGB);
    img.loadPixels();
    for (int i = 0; i < img.pixels.length; i++) {
      img.pixels[i] = color(0, 90, 102); 
    }
    img.updatePixels();
    image(img, 68, 68);
    
    Image output for example 1
  • size(400,400);
    PImage img = createImage(264, 264, ARGB);
    img.loadPixels();
    for (int i = 0; i < img.pixels.length; i++) {
      img.pixels[i] = color(0, 90, 102, i % img.width); 
    }
    img.updatePixels();
    image(img, 68, 68);
    image(img, 136, 136);
    Image output for example 2

Syntax

  • createImage(w, h, format)

Parameters

  • w(int)width in pixels
  • h(int)height in pixels
  • format(int)Either RGB, ARGB, ALPHA (grayscale alpha channel)

Return

  • PImage