Name

matchRows()

Class

Table

Description

Finds the rows in the Table that match the regular expression provided, and returns references to those rows. Returns an iterator, so for must be used to iterate through all the rows, as shown in the example above. The column to search may be specified by either its ID or title.

Examples

  • Table table;
    
    void setup() {
    
      table = new Table();
    
      table.addColumn("name");
      table.addColumn("type");
    
      TableRow newRow = table.addRow();
      newRow.setString("name", "Lion");
      newRow.setString("type", "Mammal");
    
      newRow = table.addRow();
      newRow.setString("name", "Snake");
      newRow.setString("type", "Reptile");
    
      newRow = table.addRow();
      newRow.setString("name", "Mosquito");
      newRow.setString("type", "Insect");
    
      newRow = table.addRow();
      newRow.setString("name", "Lizard");
      newRow.setString("type", "Reptile");
      
      for (TableRow row : table.matchRows("R.*", "type")) {
        println(row.getString("name") + ": " + row.getString("type"));
      }
    }
    
    // Sketch prints:
    // Snake: Reptile
    // Lizard: Reptile
    

Syntax

  • .matchRows(regexp, column)
  • .matchRows(regexp, columnName)

Parameters

  • regexp(String)the regular expression to match
  • column(int)ID number of the column to search
  • columnName(String)title of the column to search

Return

  • Iterable<TableRow>